Bye bye -services!
When you are building an application that uses the Flex FDS or ColdFusion servers as a back-end you need to define in your FlexBuilder project properties an additional compiler argument, -services. Why? FlexBuilder needs this argument/path to your services-config.xml file so it can pull just a few pieces of information out of the xml file. In turn, these pieces of information are what allows your flex client application to know what server to talk to and how. However, this has a few drawbacks.
- You need to be able to access your services-config.xml file. Which can be difficult if you are developing against a remote Flex server. Confusion with the launch url in FlexBuilder.
- By default endpoint urls in the services-config.xml use wildcards to define the host/port of the url "{server.host} and {server.port}". However, the default for FlexBuilder is to launch flex applications with a file://c:\ absolute path, easily corrected but still the default. Now the problem is that if your movie is launched with a file:// path, Flex can't use the {server.host}/{server.port} wildcards (there is no http url to pull the host and port from)
- But, you can't hardcode the url in services-config.xml either. Otherwise your .swf will be compiled with a url that points back to your development server. And you don't want to recompile the .swf for production because then the .swf you tested is NOT the same .swf as the one you deploy. (you always want to deploy the same code you test). Context-root problems, if you develop with one context-root and deploy to production under a different context-root - Watch out!
- Because the context-root needs to be hard coded in the services-config.xml or defined as a compiler argument in FlexBuilder too, it is compiled into the swf as a hard coded value. Which means, you need a different .swf for each platform you run one (a testing nightmare).
Alas, there is a solution! (You knew I was going there didn't you). All of this can be defined at runtime without the -services argument and the services-config.xml. Defining this at runtime also has a few advantages.
- Your context-root can be defined at runtime as a FlashVar and your .cfm or .jsp can easily set that with a simple variable.
- You can switch URL's as needed, for instance if the movie is loaded under an http:// url, use the wildcards. If it's loaded under a file:// or c:\.. path use a hard coded development url.
- Different developer enviroments and configurations don't matter, everyone should be able to drop the code, sorry sync from source control, on their machine and run the application.
There are different ways to do this but how I do it is with 2 files; a ConfigModel class and a standard ServiceLocator class.
ConfigModel.as
package model
{
import mx.core.Application;
import mx.controls.Alert;
import mx.utils.ObjectUtil;
/**
* Used to store Application config settings, and the
* FlashRemoting channel and endpoint url settings, with this you
* won't need define a -services compiler argument for the project.
*
* @author: Mike Nimer
**/
[Bindable(event="configChange")]
public class ConfigModel
{
public static var TIMEZONEOFFSET:Number; //est=4 or 5, depending on DST
// debug setting to switch between live and stub data
public static const USE_STUB_DATA:Boolean = false;
// Flash remoting config issues
public static const CHANNELID:String = "orca-amf";
private static const default_context_root:String = "/"; // adjust as needed for your default server.
/**
* pull the context-root out of the flash var, if it's defined in your <object/> or <embed/> tags.
* ex: contextRoot=/flex
**/
private static function get CONTEXT_ROOT():String
{
var app:Application = Application.application as Application;
if( app.parameters.contextRoot != null )
{
//Alert.show( ObjectUtil.toString(app.parameters) );
return app.parameters.contextRoot;
}
return ConfigModel.default_context_root;
}
// return the correct endpoint, if this is server from an HTTP request
// return the default localhost:8500 for development, if FlexBuilder launches
// the application locally with an absolute path (file://c:\...)
public static function get AMFENDPOINT():String
{
var app:Application = Application.application as Application;
if( app.url != null && app.url.indexOf("http:") != -1 )
{
return "http://{server.name}:{server.port}" + ConfigModel.CONTEXT_ROOT +"/messagebroker/amf";
// for ColdFusion users
// return "http://{server.name}:{server.port}" + ConfigModel.CONTEXT_ROOT +"/flex2gateway";
}
else
{
return "http://localhost:8500" + ConfigModel.CONTEXT_ROOT + "/messagebroker/amf";
// for ColdFusion Users
// return "http://localhost:8500" + ConfigModel.CONTEXT_ROOT + "/flex2gateway";
}
}
}
}
ServiceLocator.as
package services
{
import model.ConfigModel;
import mx.messaging.Channel;
import mx.messaging.ChannelSet;
import mx.rpc.remoting.mxml.RemoteObject;
import mx.rpc.events.ResultEvent;
import mx.messaging.channels.AMFChannel;
import mx.rpc.events.FaultEvent;
import mx.rpc.AbstractService;
import mx.messaging.config.ServerConfig;
/**
* Create the RemoteObject tags used by the application service delegates
* @author: Mike Nimer
**/
public class ServiceLocator
{
public var service:AbstractService;
public var amfChannelSet:ChannelSet;
public static var serviceLocator:ServiceLocator;
public function ServiceLocator()
{
var amfChannel:Channel = new AMFChannel(ConfigModel.CHANNELID, ConfigModel.AMFENDPOINT);
amfChannelSet = new ChannelSet();
amfChannelSet.addChannel(amfChannel);
}
public static function getInstance():ServiceLocator
{
if( ServiceLocator.serviceLocator == null )
{
ServiceLocator.serviceLocator = new ServiceLocator();
}
return ServiceLocator.serviceLocator;
}
/**
* Individual Services used by the Application.
**/
public function getSomeService():AbstractService
{
if( service != null )
{
return service;
}
service = new RemoteObject('someDestination');
service.channelSet = this.amfChannelSet;
(service as RemoteObject).showBusyCursor = true;
// service.source = "dot.path.to.cfc" // If you are using ColdFusion
//service.setCredentials(username, password); // if you need it
return service;
}
}
}
Set Context-root FlashVar (ColdFusion)
// You'll find this in the default html flex generates, just make the html page a cfm and add this FlashVar.
// note: Use contextRoot=<%=request.getContextPath()%> for JSP pages.
AC_FL_RunContent(
"src", "Orca",
"width", "100%",
"height", "100%",
"align", "middle",
"id", "Orca",
"quality", "high",
"bgcolor", "#869ca7",
"name", "Orca",
"flashvars",'contextRoot=#getContextRoot()#&historyUrl=history.htm%3F&lconid=' + lc_id + '',
"allowScriptAccess","sameDomain",
"type", "application/x-shockwave-flash",
"pluginspage", "http://www.adobe.com/go/getflashplayer"
);
Thanks!
The return statement cannot be used in static initialization code.
on lines 43 & 46 in model/ConfigModel.as
Please delete this foolish comments :)
Thanks, cool idea - I'm still new to eclipse, BUT isn't there a way to setup vars and use them within the IDE? One of the problems I see with using the flashvars here as you suggested, is you still need to edit the html-template for each project. (doesn't seem to be a huge shortcut)
My preference would be to setup a value somewhere in Eclipse \ (actually I use Flexbuilder ) to note the current "testing" setup and then change change that value when I'm ready to deploy.
--- I might be mistaken, and MAYBE, this functionality is there, but it's not documented or discussed anywhere that I can find. --- Info on "context-root" and the services.xml file is sparse.
I spoke briefly with Tom Lane (on Flexbuilder team) he contridicted what you say here about what the -context-root "" setting is used for. He said it's only for Java server stuff, has nothing to do with the deployment pathing and should be left blank.
I posted this question to Ben Forta in the past:
He said this is where you make the changes, that you simply create different service.xml files for each deployment scenerio. Ben is great, but that didn't work well with the CRUD wizards.
and now I'm here reading your post, which agrees with Ben's Logic, and suggests the opposite of what Tom on the Flexbuilder team tells me!
So I'm completely confused... Maybe you can futher explain the context-root and -services compliler options, and the service.xml files?
Here's why!! - I rarely test or deploy off the webroot. I use the CRUD wizards all the time to code 90% of the remoting and db intereaction of my flex apps. I'm exhaused with using "find in files" to search and replace server deployment values each time I re-run the wizard.
A better understanding of the IDE, the compiler options and service.xml would be helpful - since I'm guessing that my frustration is not singular. Maybe you or one of your readers, have some suggestions?
Keep up the great work!
There are ways to set up vars, and you can use them in eclipse. However, that has nothing to do with this problem/solution. They are good for things like project library properties.
So I think the thing you are missing is that for flash to talk to a server, it needs to call a servlet - a file at a specific url.
Tom is right context roots are java stuff on the server. But I think he is talking about something different. When you deploy a java servlet (the flex servlet) you do it under a context-root on the server, which could be blank or it could be a "/something" string. Now you can hard code the path to the context-root in the url that is used by flash client. But if you deploy your local/dev/test/production servers under different context-roots (so the url is different), then you need to use a variable in the url.
If you hard code the path to the url, then Tom is right you don't need it or you can leave it blank. However, if your path is dynamic and you use the "{context-root}" variable in the endpoint url to your servlet, then you can define that at compile time with the -context-root compiler flag, or as a FlashVar at runtime as I've described above. Basically if your using context roots then you need to worry about it, if your not then don't worry about it.
And Ben is right too. However, he is saying that you should define services-config.xml files for each of your different configurations. The problem with this, you have to re-compile the swf for each server configuration. What I've described in my post was a different way to do the same thing. I didn't want to recompile for each server configuration, I wanted one swf to work on all configs for all developers. We are both describing different solutions for the same problem.
So really it's just a matter of defining the right url to the flex server servlet in your flash client. Iif your urls are the same on all of your different server configurations (dev, production, etc.) Just hard code the url, and don't worry about all of this context-root stuff. If it is different you need to decide how to handle it; multiple service-config.xml files or runtime settings.
how to use your method to replace the following two mx:RemoteObject? Do i need to setup two diffenect getSomeService() methods in ServiceLocator.as? I appreciate you provide examples on how to use it.
<mx:RemoteObject
id="productService"
destination="ColdFusion"
makeObjectsBindable="true"
source="store.business.Product"
showBusyCursor="true">
<mx:method name="getAllProducts"
result="handleGetProductResult(event)"
fault="Alert.show(event.fault.message)" />
</mx:RemoteObject>
<mx:RemoteObject
id="creditCardService"
destination="ColdFusion"
makeObjectsBindable="true"
source="store.business.CreditCard"
showBusyCursor="true">
<mx:method name="getAllCreditCards"
result="handleGetProductResult(event)"
fault="Alert.show(event.fault.message)" />
</mx:RemoteObject>
How do you set/define the service's <adapter-definition> in AS? The livedocs just say you have to put it in the services-config and reference that. Doesn't that affect how dynamic you can get with AS service definitions?
We just have a local services-config.xml stored at the same level as the base 'src' directory, and compile against that. All our devs have local CF installs and setup Eclipse for that, so we can leave the {} place holders in and it Just Works.
I guess I'm really trying to understand where/how the compiled SWF is asking for the path to the "services-config.xml". Using CF7.02 for Flex 3beta3 (company won't purchase till this is deployed).
Many different configurations going from "sandbox" to development, staging/testing, production (we can't be like most shops who have mirrored environment configurations --frustrated sarcasm--)…
and we can not be changing the path to the services-config.xml file for each migration to the next environment. should I try mapping something? couldn't we just put the call to the CGI vars in the
CFM wrapper and pass them in? If we do that, what var is the SWF looking for in the FlashVars to pass in? Would I be using the same var passed in from Application.application.parameters.PASSED IN VAR and use it in my RemoteObject?
RemoteObject endpoint setting. Works like a charm.
we have a shared development server, so I don't need to worry about the "file//c:\" situation.
U can just use relative paths......
If you need to connecto to yout amf endo point and its url is in a secure environment (a.k.a. HTTPS) you need to change the AMFChannel to a SecureAMFChannel. Took me some time to figure it.
I am newt o Flex and BlazeDS. Going through the post , just thought can we do following -
1. Read the endpoint from a xml file , using <mx:HttpService> ,like they do in a lot of examples in Tour-De-Flex.
2. In the <mx:RemoteObject > use endPoint as the value read from the xml.
Though this would mean that you will have to change the XML file at the deployment time. But this could be like
chaning a web.xml of a web project.
http://www.psii.org
http://www.gogoer.com
http://www.srogold.com
http://www.wowgoldone.com
<a href="http://www.gamekoo.com/product/Knight_online_Noah.... gold</a> is one of the hardest theme for every class at the beginning . You must have a good way to manage your <a href="http://www.gamekoo.com/product/Knight_online_Noah.... noah</a>.If yor are a lucky guy ,you can earn so many <a href="http://www.gamekoo.com/product/Knight_online_Noah.... online gold</a>
by yourself . But if you are a not , I just find a nice way to get <a href="http://www.gamekoo.com/product/Knight_online_Noah.... online noah</a>. If you need , you can buy <a href="http://www.gamekoo.com/product/Knight_online_Noah.... knight gold</a> at our website . Go to the related page and check the detailed information . Once you have any question , you can connect our customer service at any time .
http://www.gmbar.com/
http://wow.gamevive.com/
http://blog.6vie.com/search/label/fashion/
inside of official Adobe servers..
where we roam labyrinths laced with magic
http://www.replicaslouisvuitton.com/2009-collectio...
<a href="http://www.meinwowgold.com/">WOW GOLD</a>
If you need to connecto to yout amf endo point and its url is in a secure environment (a.k.a. HTTPS) you need to change the AMFChannel to a SecureAMFChannel. Took me some time to figure it. http://telkixxxboyss.ru http://sexxxxtrajh.ru http://sexytrahxxxj.ru http://sexyxtraxk.ru http://telkdixxxboyss.ru
<a href="http://www.meinwowgold.com/">WOW GOLD</a>